Excel Thỉnh Vũ

Chia sẻ kiến thức Excel ứng dụng vào công việc thực tế với đa dạng các chủ đề và tình huống hay
Hiển thị các bài đăng có nhãn Exceltimkiem. Hiển thị tất cả bài đăng
Hiển thị các bài đăng có nhãn Exceltimkiem. Hiển thị tất cả bài đăng

Chia sẻ công thức Excel tìm kiếm từ dưới lên

 Trong thực tế nhiều tình huống bố cục dữ liệu có giá trị trùng lặp hoặc lấy số liệu từ bảng chi tiết thì người dùng cần lấy giá trị cuối cùng từ trên xuống hoặc giá trị đầu tiên từ dưới lên. 

CÔNG THỨC EXCEL TÌM KIẾM LẤY GIÁ TRỊ CUỐI CÙNG

Ví dụ tình huống: 1 sản phẩm nhiều dòng và giá bán khác nhau

Trường hợp 1: Tìm kiếm lấy dữ liệu dòng cuối cùng thỏa mãn 1 điều kiện

Ví dụ: Lấy giá SPA ở dòng cuối cùng

Công thức tìm kiếm lấy giá trị ở dòng cuối cùng áp dụng với mọi phiên bản Office:

=LOOKUP(2,1/($A$2:$A$13=F2),$C$2:$C$13)

Công thức tìm kiếm lấy giá trị ở dòng cuối cùng áp dụng với Office 365

=XLOOKUP(F2,$A$2:$A$13,$C$2:$C$13,,0,-1)

Trường hợp 2: Tìm kiếm lấy dòng dữ liệu cuối cùng thỏa mãn 2 điều kiện trở lên

Ví dụ: Lấy giá của SPA, loại 1 ở dòng cuối cùng

Công thức tìm kiếm lấy giá trị ở dòng cuối cùng áp dụng với mọi phiên bản Office

=LOOKUP(2,1/($A$2:$A$13=F2)/($B$2:$B$13=G2),$C$2:$C$13)

Công thức tìm kiếm lấy giá trị ở dòng cuối cùng áp dụng với Office 365

=XLOOKUP(F2&G2,$A$2:$A$13&$B$2:$B$13,$C$2:$C$13,,0,-1)

Trường hợp 3: Tìm kiếm lấy dữ liệu theo theo ngày gần nhất

Tham khảo công thức TẠI ĐÂY

Liên hệ tư vấn khóa học Excel cho người đi làm & đặt hàng đào tạo tại doanh nghiệp
{Đt Zalo} - 038 696 1334





Chia sẻ công thức Excel tìm ngày phát sinh cuối cùng

Trong thực tế có nhiều bảng dữ liệu được bố cục theo dạng lưới như: Bảng chấm công, bảng theo dõi phép, lưới kế hoạch sản xuất. Khi đó, người dùng cần tìm ra ngày phát sinh cuối cùng theo từng đối tượng cụ thể

Tình huống ví dụ: Theo dõi lưới sản lượng sản xuất

Yêu cầu: Cần tìm ra ngày cuối cùng có phát sinh sản xuất của từng sản phẩm

CÔNG THỨC EXCEL TÌM NGÀY PHÁT SINH CUỐI CÙNG

- Với Office 2010 trở lên

=AGGREGATE(14,6,$B$2:$P$2/(B3:P3<>""),1)

- Với Office 2019 trở lên

=MAXIFS($B$2:$P$2,B3:P3,"<>")

Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp
{Đt Zalo} - 038 696 1334


Chia sẻ công thức Excel tìm giá theo ngày niêm yết gần nhất

 Trong thực tế chính sách giá bán hàng luôn thay đổi theo thời gian, một sản phẩm có thể có nhiều lần thay đổi giá. Đồng thời phải đảm bảo nguyên tắc: Khi thay đổi giá thì số liệu của những thời điểm trước đó không được thay đổi theo.

Ví dụ tình huống: Sản phẩm A niêm yết giá thay đổi vào các ngày 01/01, 15/02, 20/03 => Tức từ 01/01-14/02 áp dụng 150,000đ, từ ngày 15/02-19/03 áp dụng 160,000đ và từ 20/03 trở đi áp dụng giá 165,000đ

CÔNG THỨC EXCEL TÌM GIÁ THEO NGÀY NIÊM YẾT GẦN NHẤT

- Trường hợp với máy tính dùng Office 2010 trở lên thì công thức tại cột G là:

=AGGREGATE(14,6,$B$2:$B$8/($C$2:$C$8=AGGREGATE(14,6,$C$2:$C$8/($A$2:$A$8=E2)/($C$2:$C$8<=F2),1))/($A$2:$A$8=E2),1)

- Trường hợp máy tính dùng Office 2019 trở lên thì công thức tại cột G là:

=MAXIFS($B$2:$B$8,$C$2:$C$8,MAXIFS($C$2:$C$8,$A$2:$A$8,E2,$C$2:$C$8,"<="&F2),$A$2:$A$8,E2)

Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp
{Đt Zalo} - 038 696 1334


Cách so sánh sự khác nhau giữa 2 bảng số liệu trên Excel

 Trong thực tế quản trị số liệu, có phát sinh nhiều tình huống cần so sánh sự khác biệt giữa 2 bảng số liệu như:

- Giữa nhập tay và từ phần mềm xuất ra

- Giữa bảng số liệu gốc và bảng số liệu sau khi sửa đổi

- Giữa bảng số liệu kế toán so với hải quan, ngân hàng, bán hàng

-...

Các bảng số liệu này thường có nhiều cột, sự khác nhau giữa 2 bảng số liệu có thể khác biệt thông tin ở 1 hoặc nhiều cột và cần tìm ra dòng nào là dòng khác biệt

Bài toán ví dụ như sau: Bảng dữ liệu 1 (A3:C13) và bảng dữ liệu 2 (G3:I13) cùng nhau về cấu trúc số cột nhưng có sự khác nhau về số liệu bên trong 2 bảng, cần tìm ra dòng nào là dòng có thông tin khác biệt

HƯỚNG DẪN CÁCH SO SÁNH SỰ KHÁC NHAU GIỮA 2 BẢNG SỐ LIỆU TRÊN EXCEL

Cách 1: Dùng cột phụ và kết hợp với hàm MATCH

Bước 1: Tạo cột phụ ghép giữa các cột ở từng bảng số liệu

Bước 2: Dùng hàm MATCH để tham chiếu tìm kiếm chéo giữa 2 bảng

Kết quả thu được; Dòng nào trả về #N/A thì dòng đó có ít nhất 1 cột thông tin có sự khác biệt

Cách 2: Dùng hàm COUNTIFS để đếm chéo giữa 2 bảng. 

Có bao nhiêu cột cần kiểm tra thì đưa bấy nhiêu điều kiện vào hàm COUNTIFS.

Kết quả thu được là dòng nào trả về 0 là dòng đó có ít nhất 1 thông tin khác bảng kia

Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp
{Đt Zalo} - 038 696 1334






Chia sẻ công thức Excel tìm kiếm dữ liệu theo điều kiện trả về nhiều dòng

 Trong thực tế, có nhiều trường hợp người dùng cần lập công thức tìm kiếm, trích xuất dữ liệu theo điều kiện nhưng kết quả trả về nhiều dòng như:

- Lập phiếu: Phiếu nhập, xuất, bán hàng, mua hàng,... => Tìm kiếm theo số phiếu nhưng trả về nhiều dòng

- Báo cáo chi tiết: Thẻ kho, Sổ quỹ,...=> Tìm kiếm theo mã và theo ngày tháng với kết quả nhiều dòng

- Trích lọc khác: Trích lọc sinh nhật trong tháng, danh sách tăng giảm,...

...

Bài toán này nếu dùng VLOOKUP thì phải qua cột phụ hoặc kết hợp với hàm CHOOSE, hoặc tạo tham chiếu cột phụ kết hợp với INDEX, MATCH...

Công thức dưới đây sẽ áp dụng không thông qua cột phụ

(Bảng dữ liệu mẫu phục vụ các ví dụ phía dưới)
HÀM INDEX KẾT HỢP CÙNG AGGREGATE VÀ ROW TRẢ VỀ KẾT QUẢ NHIỀU DÒNG
(Áp dụng từ Office 2010 trở lên)
Ví dụ tình huống: Tìm kiếm dữ liệu theo số chứng từ. Điều kiện Số chứng từ tại ô J1
Công thức lấy ra các dòng ngày của theo số chứng từ:
=IFERROR(INDEX($A$3:$A$15,AGGREGATE(15,6,ROW($1:$15)/($B$3:$B$15=$J$1),ROW(1:1))),"")
Trong đó:
- A3:A15 là cột ngày tương ứng của bảng dữ liệu. Khi đó các cột Diễn giải, mã hàng, số lượng,...thay bằng tham chiếu các cột tương ứng bên bảng dữ liệu nguồn
- ROW($1:$15) tham chiếu số dòng từ bảng dữ liệu (luôn bắt đầu từ dòng 1 tức $1:..)
- ($B$3:$B$15=$J$1) là mảng điều kiện: Cột số c.từ của bảng dữ liệu nguồn so sánh với ô J1 điều kiện
=> Thực hiện kéo công thức cho nhiều dòng (có thể kéo thừa dòng chờ)

DÙNG HÀM FILTER TRONG OFFICE 365 TRẢ VỀ KẾT QUẢ NHIỀU DÒNG

Công thức lấy ra dữ liệu các cột theo số chứng từ:
=FILTER(A3:G15,B3:B15=J1)
Hàm Filter trong Office 365 trả về mảng giá trị nên không phải kéo công thức

Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp
{Đt+Zalo} - 038 696 1334

Hướng dẫn dùng hàm MINIFS hoặc AGGREGATE để tìm giá trị nhỏ nhất có điều kiện và đối tượng tương ứng với giá trị đó

 Trong thực tế, có rất nhiều bài toán quản trị cần tìm giá trị nhỏ nhất thỏa mãn một hoặc nhiều điều kiện, và tìm ra đối tượng tương ứng với giá trị đó. Ví dụ như:

- Tìm ra  doanh số nhỏ nhất và của nhân viên nào

- Tìm ra giá bán thấp nhất của mặt hàng nào, thời gian bán hàng tương ứng

-....

(Hình ảnh dữ liệu phục vụ cho các ví dụ minh họa bên dưới)

HƯỚNG DẪN TÌM GIÁ TRỊ NHỎ NHẤT CÓ ĐIỀU KIỆN

Tình huống 1: Tìm ra doanh số nhỏ nhất của KH004

Công thức dành cho mọi bản Office:

=MIN(IF(B4:B15="KH004",C4:C15))

=> Nhấn Ctrl+Shift+Enter để chạy công thức. Với Office 365 thì nhấn phím Enter bình thường

Công thức dành cho Office 2010 trở lên:

=AGGREGATE(15,6,C4:C15/(B4:B15="KH004"),1)

Công thức dành cho Office 2016 trở lên

=MINIFS(C4:C15,B4:B15,"KH004")

Tình huống 2: Tìm ra doanh số nhỏ nhất của KH004 trước ngày 15/01/2021

Công thức cho mọi bản Office:

=MIN(IF((B4:B15="KH004")*(A4:A15<=Date(2021,1,15)),C4:C15))

=> Nhấn Ctrl+Shift+Enter để chạy công thức. Với Office 365 thì nhấn phím Enter bình thường

Công thức dành cho Office 2010 trở lên: 

=AGGREGATE(14,6,C4:C15/(B4:B15="KH004")/(A4:A15<=Date(2021,1,15)),1)

Công thức dành cho Office 2016 trở lên:

=MINIFS(C4:C15,B4:B15,"KH004",A4:A15,"<="&Date(2021,1,15))

Tình huống 3: Tìm ra khách hàng có doanh số lớn nhất

=LOOKUP(2,1/(C4:C15=MIN(C4:C15)),B4:B15)

Trường hợp có nhiều hơn 1 khách hàng có doanh số nhỏ nhất thì phải dùng hàm TEXTJOIN để liệt kê ra danh sách khách hàng có doanh số nhỏ nhất. Hàm TEXTJOIN có trong Office 2019 trở lên và Office 365

==TEXTJOIN(",",TRUE,IF(C4:C15=MIN(C4:C15),B4:B15,""))

Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp
{Đt+Zalo} - 038 696 1334

Hướng dẫn dùng hàm MAXIFS hoặc AGGREGATE để tìm giá trị lớn nhất có điều kiện và đối tượng tương ứng với giá trị đó

Trong thực tế, có rất nhiều bài toán quản trị cần tìm giá trị lớn nhất thỏa mãn một hoặc nhiều điều kiện, và tìm ra đối tượng tương ứng với giá trị đó. Ví dụ như:

- Tìm ra đơn hàng có doanh số lớn nhất và của khách hàng nào, vào thời gian nào

- Tìm ra giá bán cao nhất của mặt hàng nào, thời gian bán hàng tương ứng

- Tìm ra chi phí lớn nhất là bao nhiêu và của loại chi phí nào

-....

(Hình ảnh dữ liệu phục vụ cho các ví dụ minh họa bên dưới)

HƯỚNG DẪN TÌM GIÁ TRỊ LỚN NHẤT CÓ ĐIỀU KIỆN

Tình huống 1: Tìm ra doanh số lớn nhất của KH004

Công thức dành cho mọi bản Office:

=MAX(IF(B4:B15="KH004",C4:C15))

=> Nhấn Ctrl+Shift+Enter để chạy công thức. Với Office 365 thì nhấn phím Enter bình thường

Công thức dành cho Office 2010 trở lên:

=AGGREGATE(14,6,C4:C15/(B4:B15="KH004"),1)

Công thức dành cho Office 2016 trở lên

=MAXIFS(C4:C15,B4:B15,"KH004")

Tình huống 2: Tìm ra doanh số lớn nhất của KH004 trước ngày 15/01/2021

Công thức cho mọi bản Office:

=MAX(IF((B4:B15="KH004")*(A4:A15<=Date(2021,1,15)),C4:C15))

=> Nhấn Ctrl+Shift+Enter để chạy công thức. Với Office 365 thì nhấn phím Enter bình thường

Công thức dành cho Office 2010 trở lên: 

=AGGREGATE(14,6,C4:C15/(B4:B15="KH004")/(A4:A15<=Date(2021,1,15)),1)

Công thức dành cho Office 2016 trở lên:

=MAXIFS(C4:C15,B4:B15,"KH004",A4:A15,"<="&Date(2021,1,15))

Tình huống 3: Tìm ra khách hàng có doanh số lớn nhất

=LOOKUP(2,1/(C4:C15=MAX(C4:C15)),B4:B15)

Trường hợp có nhiều hơn 1 khách hàng có doanh số lớn nhất thì phải dùng hàm TEXTJOIN để liệt kê ra danh sách khách hàng có doanh số lớn nhất. Hàm TEXTJOIN có trong Office 2019 trở lên và Office 365

==TEXTJOIN(",",TRUE,IF(C4:C15=MAX(C4:C15),B4:B15,""))


Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp
{Đt+Zalo} - 038 696 1334

Chia sẻ công thức Excel lấy mã theo danh mục hành chính

 Trong việc lập danh sách các đối tượng tiêm hoặc quản lý thông tin hành chính của địa phương hoặc doanh nghiệp cụ thể thì cần lấy mã Tỉnh thành, Quận Huyện, Xã Phường từ bảng Danh mục hành chính sang bảng danh sách đối tượng. Tuy nhiên, đặc thù ở Việt Nam thì khá nhiều tỉnh thành có tên Quận/Huyện hoặc Phường/Xã trùng tên nhau. Ví dụ như: Phường Minh Khai trùng tên ở nhiều Tỉnh/Thành

Trường hợp này, nếu dùng hàm VLOOKUP đơn giản để lấy ra mã Quận/Huyện hoặc Xã/Phường thì sẽ xảy ra sai xót. Khi đó, bài toán này sẽ được giải quyết bằng phương pháp tìm kiếm nhiều điều kiện. Trong bài hướng dẫn này sẽ sử dụng hàm LOOKUP


Giả lập bài toán gồm 02 sheet:

- PL1_Danh sach doi tuong tiem: Cột A là tên Tỉnh/Thành, C là tên Quận/Huyện, E là tên Xã/Phường. Cột B, D, F là các cột cần làm công thức để lấy ra mã địa giới tương ứng
- PL3_Danh muc hanh chinh: Bảng dữ liệu danh mục có hơn 1000 dòng (đầy đủ các mã địa chỉ hành chính). Và bảng danh mục hành chính này là cố định cột theo mẫu chung
Công thức lấy ra mã tỉnh thành ở cột B sheet PL1_Danh sach doi tuong tiem

=LOOKUP(96,69/(A2='PL3_Danh muc hanh chinh'!$A$2:$A$10605),'PL3_Danh muc hanh chinh'!$B$2:$B$10605)

Cách dùng: Theo bảng dữ liệu thực tế thì chỉ cần thay ô A2 là ô tên Tỉnh/Thành. 
(trường hợp này có thể dùng hàm VLOOKUP)

Công thức lấy ra mã Quận/Huyện ở cột D sheet PL1_Danh sach doi tuong tiem

=LOOKUP(96,69/(A2='PL3_Danh muc hanh chinh'!$A$2:$A$10605)/(C2='PL3_Danh muc hanh chinh'!$C$2:$C$10605),'PL3_Danh muc hanh chinh'!$D$2:$D$10605)

Cách dùng: Theo bảng dữ liệu thực tế thì chỉ cần thay ô A2 và ô C2 để tìm kiếm theo 2 điều kiện: Tên tỉnh thành và tên quận huyện

Công thức lấy ra mã Xã/Phường ở cột F sheet PL1_Danh sach doi tuong tiem

=LOOKUP(96,69/(A2='PL3_Danh muc hanh chinh'!$A$2:$A$10605)/(C2='PL3_Danh muc hanh chinh'!$C$2:$C$10605)/(E2='PL3_Danh muc hanh chinh'!$E$2:$E$10605),'PL3_Danh muc hanh chinh'!$F$2:$F$10605)

Cách dùng: Theo bảng dữ liệu thực tế thì chỉ cần thay ô A2, C2, E2 để tìm kiếm theo 3 điều kiện: Tên tỉnh thành và tên quận huyện và tên phường xã


Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp

{Đt+Zalo} - 038 696 1334

Chia sẻ công thức Excel quy đổi lương NET sang GROSS

 Chia sẻ công thức Excel quy đổi lương Net Grosss trong Excel để tính ra thu nhập tính thuế


File Excel mẫu có chứa công thức quy đổi lương Net Gross: DOWNLOAD

Diễn giải tình huống công thức:

- Ô A5 cột thu nhập cần quy đổi (số tiền cần quy đổi). Khi dùng công thức vào bảng tính thì chỉ cần thay địa chỉ ô A5 là được.

- Công thức chi tiết:

Công thức 1 (cách 1) - Sử dụng hàm LOOKUP: 

=LOOKUP(A5,{0,475,925,1605,2725,4225,6185}*10^4+10^-6,100*(A5-{0,25,75,165,325,585,985}*10^4)/{95,90,85,80,75,70,65})

Công thức 2 (cách 2) - Sử dụng hàm IF:

=IF(A5>6185*10^4,(A5-985*10^4)/65,IF(A5>4225*10^4,(A5-585*10^4)/70,IF(A5>2725*10^4,(A5-325*10^4)/75,IF(A5>1605*10^4,(A5-165*10^4)/80,IF(A5>925*10^4,(A5-75*10^4)/85,IF(A5>475*10^4,(A5-25*10^4)/90,A5/95))))))*100


Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp

{Đt+Zalo} - 038 696 1334

Hướng dẫn tìm kiếm ngược từ phải sang trái trong Excel

 Trong Excel thì hàm VLOOKUP là hàm tìm kiếm thông dụng nhất mà đa số người dùng Excel đều biết. Cách thức hoạt động tìm kiếm của hàm VLOOKUP là tìm kiếm từ trái sang phải. Trong đó, cột đầu tiên là cột chứa giá trị tìm kiếm. Nhưng trong thực tế thì có nhiều trường hợp cần tìm kiếm ngược - tức tìm kiếm từ phải sang trái => Đồng nghĩa là cột chứa giá trị tìm kiếm ở bên phải, cột chứa giá trị trả về ở bên trái. 

Videos dưới đây sẽ hướng dẫn người dùng phương pháp tìm kiếm từ phải sang trái - tìm kiếm ngược theo các cách như sau:

- Hàm VLOOKUP kết hợp với hàm CHOOSE

Công thức: =VLOOKUP(G2,CHOOSE({1,2},D2:D13,C2:C13),2,0)

- Hàm INDEX kết hợp với hàm MATCH

Công thức: =INDEX(C2:C13,MATCH(G2,D2:D13,0))

- Hàm LOOKUP

Công thức: =LOOKUP(2,1/(D2:D13=G2),C2:C13)

- Hàm XLOOKUP (Có trong Office 365)

Công thức: =XLOOKUP(G2,D2:D13,C2:C13,"")


Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp

{Đt+Zalo} - 038 696 1334

Sử dụng hàm LOOKUP mảng thay thế hàm IF lồng ghép

 Trong Excel nâng cao thì hàm Lookup là hàm khá đa năng trong tìm kiếm và được ứng dụng như:

- Tìm kiếm tương đối trong khoảng điều kiện: Giống Vlookup tìm kiếm kiểu TRUE

- Giá trị truyền vào là tập hợp mảng giá trị

Nhưng bản chất của Lookup là tìm kiếm tương đối và loại bỏ giá trị lỗi khi tìm kiếm nên được mệnh danh là hàm tìm kiếm cao cấp, ứng dụng trong những tình huống tìm kiếm nhiều điều kiện, tìm kiếm theo mảng rất tốt.

Videos dưới dây sẽ hướng dẫn sử dụng hàm lookup theo ví dụ đơn giản là tìm kiếm trong khoảng giá trị (cách dùng giống với Vlookup tìm kiếm tương đối)


Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp

{Đt+Zalo} - 038 696 1334

Sử dụng hàm Vlookup tìm kiếm tương đối để rút ngắn công thức IF lồng ghép

 Hàm Vlookup tìm kiếm tương đối được ứng dụng rất nhiều trong các bài toán xét điều kiện trong khoảng. Điển hình như:

- Xét học lực, xếp loại học tập

- Xét KPI

- Tính thuế

- Tính thưởng

- Tính phạt

- Tính chiết khấu, giảm giá

....

Các bài toán này đều có đặc điểm chung là đều có khoảng giá trị điều kiện (từ bao nhiêu đến bao nhiêu thì được kết quả là gì). Với dạng bài toán này thì nhiều người hay nghĩ tới phương án dùng hàm IF, nhưng phương án này sẽ gặp phải những hạn chế lớn:

- Nhiều khoảng điều kiện thì sẽ có nhiều hàm IF lồng ghép với nhau, người lập công thức không cẩn thận hoặc không có phương pháp lồng ghép tốt thì sẽ dễ nhầm, sai kết quả, lỗi công thức

- Hàm IF sẽ có giới hạn số lượng cấp lồng (Level If), nhiều bài toán có quá nhiều điều kiện khoảng thì hàm IF sẽ báo lỗi vượt Level

- Phải sắp xếp điều kiện để khối IF lồng ngắn gọn hơn, nếu không sắp xếp điều kiện thì phải hối hợp thêm hàm AND, OR, Not và làm công thức dài hơn.

Để khắc phục những hạn chế này, videos dưới đây sẽ hướng dẫn cách dùng hàm VLOOKUP tìm kiếm tương đối với tham số cuối cùng kiểu TRUE hoặc 1. Khi đó chỉ cần dùng 1 hàm VLOOKUP thì sẽ được kết quả tương đương, công thức ngắn gọn hơn rất nhiều.


Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp

{Đt+Zalo} - 038 696 1334

TÍNH LƯƠNG THƯỞNG THEO DOANH SỐ KINH DOANH TRONG EXCEL

TÍNH LƯƠNG THƯỞNG THEO DOANH SỐ KINH DOANH TRONG EXCEL 

Đây là một bài toán được ứng dụng rất nhiều trong thực tế để phục vụ tính lương, thưởng, chiết khấu hoặc thậm trí là tính phạt theo doanh số. Bản chất của bài toán này là: Mỗi khoảng sẽ có chính sách thưởng phạt riêng và con số đạt được sẽ nằm trong khoảng nào thì sẽ tính theo khoảng đó.

Thông thường cách giải quyết bài toán này thì mọi người hay dùng hàm IF kết hợp với hàm AND, OR...để xử lý các khoảng điều kiện. Tuy nhiên, đối với bài toán lớn có nhiều điều kiện thì việc lồng ghép hàm IF gặp nhiều trở ngại, thậm trí là vượt quá giới hạn lồng ghép của Excel. Vì vậy, phương án xử lý cho bài toán này là: Sử dụng phương pháp tìm kiếm tương đối hay còn gọi là tìm kiếm kiểu TRUE trong Excel. 

Tham khảo videos hướng dẫn tính lương thưởng theo doanh số dưới đây.

- Ứng dụng hàm Vlookup

- Có thể thay thế bằng hàm LOOKUP hoặc INDEX MATCH


Liên hệ tư vấn khóa học Excel cho người đi làm hoặc đặt hàng đào tạo tại doanh nghiệp

{Đt+Zalo} - 038 696 1334

Đăng ký: Bài đăng (Atom)
Excel Thỉnh Vũ. Được tạo bởi Blogger.

Biên tập: Excel Thỉnh Vũ
Ủng hộ phát triển Blog theo STK: 0451000318287 Vu Duc Thinh - Ngân hàng Vietcombank
Liên hệ tư vấn khóa học Excel - {ĐT+Zalo} 038 696 1334 - Email: excel.coban.nangcao@gmail.com