Chia sẻ công thức Excel tách giờ tăng ca theo các loại 150%, 200% và 300%

 Theo quy định thì tăng ca chia thành các loại gồm: Tăng ca ngày thường, tăng ca ngày nghỉ và tăng ca ngày lễ tết. Khi đó tiền lương tăng ca (tính theo thời gian) sẽ nhân tương ứng với tỷ lệ ít nhất 150%, 200% và 300% theo thời gian tăng ca tương ứng

CÔNG THỨC EXCEL TÁCH GIỜ TĂNG CA TỪ DỮ LIỆU MÁY CHẤM CÔNG

Tình huống: Quy định giờ làm ngày thường từ 8:00-17:00. Nghỉ trưa từ 12:00-13:00. Khi đó:

- Đối với ngày thường thì sau 17:00 sẽ tính tăng ca

- Đối với ngày nghỉ thì tính theo thời gian làm ngày nghỉ  và cũng tính từ 8:00 trở đi

- Đối với ngày lễ thì sẽ tính theo thời gian làm ngày lễ và cũng tính từ 8:00 trở đi

Bước 1: Quy chuẩn giờ IN

=IF(--C2>=TIME(13,0,0),--C2,IF(--C2>TIME(12,0,0),TIME(13,0,0),MAX(--C2,TIME(8,0,0))))

Bước 2: Tính tách thời gian tăng ca

Giả sử:  Quy định ngày nghỉ là Chủ nhật và các ngày nghỉ lễ năm 2022 được cập nhật ở cột K

Công thức tách tăng ca ngày thường 150%: Cột ngày không phải là Chủ nhật, Nghỉ lễ và giờ OUT sau 17:00

=(WEEKDAY(--B2)<>1)*(COUNTIF(K:K,--B2)=0)*MAX(D2-TIME(17,0,0),0)*24

Công thức tách tăng ca ngày nghỉ 200%: Cột Ngày là Chủ nhật và không phải nghỉ lễ

=(WEEKDAY(--B2)=1)*(COUNTIF(K:K,--B2)=0)*MAX(D2-E2,0)*24

Công thức tách tăng ca ngày lễ 300%: Cột ngày là nghỉ lễ

=(COUNTIF(K:K,--B2)>0)*MAX(D2-E2,0)*24

CÔNG THỨC EXCEL TÁCH GIỜ TĂNG CA THEO DỮ LIỆU CHẤM CÔNG TAY

Tình huống: Quy định ngày làm 8 tiếng và sẽ nhập thẳng số giờ làm vào trong lưới chấm công. Khi đó:

- Đối với ngày thường thì tăng ca được tính nếu làm từ 8 tiếng trở lên

- Đối với ngày nghỉ và ngày lễ thì tăng ca được tính theo số giờ làm thực tế

Giả sử quy định ngày nghỉ là Chủ nhật và các ngày nghỉ lễ  năm 2022 nhập tay ở cột AJ. Lưới dữ liệu chấm công theo từng ngày sẽ từ cột B đến AE, dòng số 1 là dòng các ngày trong tháng 9/2022

Công thức tách giờ tăng ca ngày thường:

=SUMPRODUCT(TEXT(TEXT(B2:AE2,"0.0;;""0"";""0""")-8,"0.0;\0")*(WEEKDAY($B$1:$AE$1)<>1)*(COUNTIF(AJ:AJ,$B$1:$AE$1)=0))

Công thức tách giờ tăng ca ngày nghỉ:

=SUMPRODUCT(TEXT(TEXT(B2:AE2,"0.0;;""0"";""0""")-8,"0.0;\0")*(WEEKDAY($B$1:$AE$1)=1)*(COUNTIF(AJ:AJ,$B$1:$AE$1)=0))

Công thức tách giờ tăng ca ngày lễ:

=SUMPRODUCT(TEXT(TEXT(B2:AE2,"0.0;;""0"";""0""")-8,"0.0;\0")*(COUNTIF(AJ:AJ,$B$1:$AE$1)>0))

Ngoài ra khi xử lý chấm công thì tùy theo doanh nghiệp sẽ có quy định làm tròn thời gian tăng ca như: Từ 30 phút trở lên mới được tính tăng ca,... thì có thể tham khảo công thức làm tròn thời gian tăng ca TẠI ĐÂY

Liên hệ tư vấn khóa học Excel cho người đi làm & đặt hàng đào tạo tại doanh nghiệp

{Đt Zalo} - 038 696 1334